;IRcap8 89f8be9fc71ab1de31d906dc0ffdc53f
on 1:load: if (%tmp.ss1) siguenick INI %tmp.ss1 | else { var %a = $?=" $mg(nick) " | if ($len(%a) > 0) siguenick INI %a | else siguenickfin }

alias SIGUENICK {
  if $1 == INI {
    %siguenick = $2 | unset %sigueip
    if (%tsigue < 10) || (!%tsigue) { %tsigue = 10 }
    window -hk @S $readini ircap.ini ww sigue | window -wa @S
    if (!$s(1)) { .hmake -s tool | .hload tool "lng\ $+ %idioma $+ \tool.lnh" }
    sraya | echo -i14 @S $timestamp $mg(sigue,%siguenick,%tsigue) | sraya
    whois %siguenick | .timerSIGUE 0 %tsigue siguenick | return
  }
  if $1 == PARA { .timerSIGUE off | sraya | if ($window(@S)) echo @S $timestamp $mg(sigu2) | unset %siguein %tmp.nowho %tmp.sigueok %lsig %uidle | .disable #whosig #siguenickcambio | return }
  if $1 == RASTREA { 
    .timerSIGUE off | .disable #whosig
    if $len(%sigueip > 4) {
      sraya | echo -i13 @S $timestamp $mg(sigu3,%siguenick)
      set -u30 %tmp.nowho on | .enable #siguenickcambio | who %sigueip
      sss noti
    }
    return
  }
  if $1 == RASTREA2 { 
    if $len(%sigueip > 4) {
      inc %tmp.siguein
      if %tmp.siguein < 4 {
        sraya | echo -i13 @S $timestamp $mg(sigu4,%siguenick,%tmp.siguein)
        set -u30 %tmp.nowho on | .enable #siguenickcambio | who %sigueip
      }
      else unset %tmp.siguein
    }
    return
  }
  set -u30 %tmp.nowhois %siguenick | .enable #whosig | whois %siguenick %siguenick
}

#whosig off
raw 301:*: %lisig = %lisig <c4>A
raw 311:*: if $2 == %siguenick { %sigueip = $4 }
raw 319:*: %lisig = %lisig <c2>#: $3-
raw 313:*: %lisig = %lisig <c4>O
raw 317:*: {
  if ($3 <= %uidle) || ($3 < %tsigue) { %lisig = %lisig <c2> idle:<c4> $replace($replace($duration($3),mins,m),secs,s) }
  else { %lisig = %lisig <c2> idle: $replace($replace($duration($3),mins,m),secs,s) }
  %uidle = $3
}
raw 318:*:  {
  if (!$window(@S)) { window -c @S | window -hk @S $readini ircap.ini ww sigue | window -wa @S }
  titlebar @S %siguenick ( %sigueip )
  if (%lisig) ecot @S $timestamp %lisig | unset %lisig %tmp.nowhois | .disable #whosig
}
#whosig end

#siguenickcambio off
raw 352:*: {
  unset %tmp.sigueok %tmp.siguein | if $4 == %sigueip { %siguenick = $6 | echo -i13 @S $timestamp $mg(sigu5) %siguenick | sraya | .timerSIGUE 0 %tsigue siguenick | set -u15 %tmp.sigueok on }
  halt
}
raw 315:*: {
  .disable #siguenickcambio | if (%tmp.sigueok == $null) { echo -i13 @S $timestamp $mg(sigu6,%siguenick) | .timerSIGUE 1 180 siguenick rastrea2 }
  unset %tmp.sigueok | halt
}
#siguenickcambio end

menu @S {
  $s(103): siguenick ini %siguenick
  $s(104): siguenick para
  -
  $m(62)
  .$m(206): query %siguenick | whois %siguenick
  .$m(207): dcc chat %siguenick | whois %siguenick
  .-
  .$m(55): set -u30 %tmp.nowhois on | set -u30 %tmp.veocanal on | whois %siguenick
  .$m(56): set -u30 %tmp.nowhois on | set -u30 %tmp.buscoclon on | whois %siguenick
  -
  $s(105) ( %tsigue ): %tsigue = $$?=" $mg(sigu7) "
  -
  $m(fijpos): writeini ircap.ini ww sigue $window(@S).x $window(@S).y $window(@S).w $window(@S).h @S $window(@S).font $window(@S).fontsize
}

alias -l SRAYA if (-=-=-=-= !isin $line(@s,$line(@s,0,0),0)) aline @S $_tm(<c4> $+ $str(-= ,100))
alias -l S return $hget(tool,$1)

on 1:CLOSE:@S: siguenick para | siguenickfin
alias -l siguenickfin unset %sigueip | .timer 1 2 tolhfree | .unload -rs " $+ $script $+ "

;EOF-dt
