;IRcap8 589c44d5a3b12f9c651fea3a5848fba0

on 1:load: dmemos %tmp.ss1

alias dmemos {
  if (!$s(1)) { .hmake -s tool | .hload tool "lng\ $+ %idioma $+ \tool.lnh" }
  %smemo.to = $readini ircap.ini VAR memoto
  if $1 != $null { set %smemo.to $1 $remtok(%smemo.to,$1,32) | .timer -m 1 300 did -c memosend 1 1 | .timer -m 1 300 did -f memosend 2 | %smemo.to = $gettok(%smemo.to,1-8,32) }
  if $dialog(MemoSend) != $null dialog -x MemoSend | dialog -m MemoSend MemoSendt
}

on *:DIALOG:MemoSend:init:0:{  
  llenamemosend
}  

alias LLENAmemosend var %i = 1 | while (%i < 9) { did -a memosend 1 $gettok(%smemo.to,%i,32) | inc %i }

dialog MemoSendt {
  title $s(85)
  size -1 -1 360 130
  combo 1,52 8 90 170,edit drop
  edit "",2,50 30 300 70,return multi vsbar limit 445

  text $s(86),102,1 12 45 24,right
  text $s(87),103,1 32 45 24,right
  text $s(88) ( 0 / 450),111,228 8 120 22,right

  button $s(89),10,150 104 200 20
  button $s(90),99,52 104 90 20, ok
}


on *:DIALOG:MemoSend:*:*: {  
  ;  titlebar $dname $devent $did  
  if ($devent == edit) && ($did == 7) { set %bmailde $did(7) }
  if ($devent == sclick) { 
    if $did == 10 { 
      if ($did(1) == $null) || ($did(2) == $null) { fallo | halt }
      mms send $did(1) $didtok(2,32)
      if $netcon(1) == hispano.inb {
        write -il1 usr\memos_ $+ $nnet $+ .mms $me --> $+ $did(1) ( $+ $time $date $+ ) $didtok(2,32)
        if $window(@memos).state != $null cargamemos
      }
      %smemo.to = $remtok(%smemo.to,$did(1),32) | set %smemo.to $did(1) %smemo.to | %smemo.to = $gettok(%smemo.to,1-8,32) | llenamemosend
      writeini ircap.ini VAR memoto %smemo.to
      unset %smemo.* | .timer 1 1 .unload -rs g-memosend.mrc | dialog -x MemoSend
    }
    if $did == 99 { unset %smemo.* | .timer 1 2 tolhfree | .timer 1 1 .unload -rs g-memosend.mrc }
  }
  if ($devent == edit) && ($did == 2) { did -a MemoSend 111 $s(88) ( $len($didtok(2,32)) / 450) }
}
alias -l S return $hget(tool,$1)

;EOF-dt
